🌐 Edit - Mathematica Stack Exchange - mathematica.stackexchange.com

You are not logged in. Your edit will be placed in a queue until it is peer reviewed.

We welcome edits that make the post easier to understand and more valuable for readers. Because community members review edits, please try to make the post substantially better than how you found it, for example, by fixing grammar or adding additional resources and hyperlinks.

Required fields*

Prevent error message on accidental mouse drag on dynamic 3d graphics

Here is an example how to use Dynamic inside Manipulate for smooth rotation. But it does not work for the following code.

Manipulate[
 Show[Graphics3D[Cube[]], 
  ViewPoint -> 
   RotationMatrix[Dynamic@fi, 
     RotationMatrix[Dynamic@fi, {0, 1, 1}] . {0, 0, 
       1}] . {1.3`, -2.4`, 2.`}], {fi, 0, 2 Pi}]

It can be solved by wrapping whole view point expression by Dynamic instead of using Dynamic@fi.

Manipulate[
 Show[Graphics3D[Cube[]], 
  ViewPoint -> 
   Dynamic[RotationMatrix[fi, 
      RotationMatrix[fi, {0, 1, 1}] . {0, 0, 1}] . {1.3`, -2.4`, 
      2.`}]], {fi, 0, 2 Pi}]

But then if you accidently click and drag the graphics by mouse an error message is thrown.

How to prevent this?

Answer*

Just for the fun of it, here's a version of this that allows you to also change the base `ViewPoint` dynamically

```
DynamicModule[{baseViewPoint = {1.3`, -2.4`, 2.`}, activeViewPoint, tfMat},
 Manipulate[
  tfMat = RotationMatrix[fi, RotationMatrix[fi, {0, 1, 1}] . {0, 0, 1}];
  Show[
   Graphics3D[Cube[]],
   ViewPoint -> Dynamic[
     tfMat . baseViewPoint,
     Function[baseViewPoint = Transpose[tfMat] . #]
     ]
   ],
  {fi, 0, 2 Pi}
  ]
 ]
```

and here's a version that allows you to customize the layout and drop the `Manipulate`

```
DynamicModule[{baseViewPoint = {1.3`, -2.4`, 2.`}, activeViewPoint, tfMat, fi},
 Panel@
  Column@{
    Panel[
     Show[
      Graphics3D[Cube[]],
      ViewPoint -> Dynamic[
        tfMat . baseViewPoint,
        Function[baseViewPoint = Transpose[tfMat] . #]
        ]
      ],
     Background -> White
     ],
    Slider[
     Dynamic[fi, 
      Function[
       fi = #;
       tfMat = RotationMatrix[fi, RotationMatrix[fi, {0, 1, 1}] . {0, 0, 1}]
       ],
      {fi, 0, 2 Pi}
      ]
     ]
    },
 Initialization :> {
   tfMat = IdentityMatrix[3],
   fi = 0
   }
 ]
```

You can get different, potentially better behaved rotations by adjusting parameters other than the `ViewPoint` like the `ViewVertical`, but those options are comprehensively discussed in other answers on this site

Edit Summary*

Cancel

Add a comment |

Correct minor typos or mistakes
Clarify meaning without changing it
Add related resources or links
Always respect the author’s intent
Don’t use edits to reply to the author

create code fences with backticks ` or tildes ~
```
like so
```
add language identifier to highlight code
```python
def function(foo):
print(foo)
```
put returns between paragraphs
for linebreak add 2 spaces at end
_italic_ or **bold**
indent code by 4 spaces
backtick escapes `like _so_`
quote by placing > at start of line
to make links (use https whenever possible)

<https://example.com>

[example](https://example.com)

<a href="https://example.com">example</a>
MathJax equations $\sin^2 \theta$

formatting help »
answering help »

MathJax help »