🌐 Edit - Stack Overflow - stackoverflow.com

You are not logged in. Your edit will be placed in a queue until it is peer reviewed.

We welcome edits that make the post easier to understand and more valuable for readers. Because community members review edits, please try to make the post substantially better than how you found it, for example, by fixing grammar or adding additional resources and hyperlinks.

Required fields*

Rev

Required fields*

How can I obtain the cube root in C++?

I know how to obtain the square root of a number using the sqrt function.

How can I obtain the cube root of a number?

Answer*

I wrote a code for calculating a cube root with single precision under Visual Studio C++ (x86). This function works, as a rule, faster than the standard function cbrtf() and is almost as accurate — the maximum error is about 1 ULP. The function works in the entire range of input values.  
  
ULP — Unit of Last Position. That is, this is an expression of the error in units of the least significant binary digit of the mantissa. It is convenient to use for numbers presented in exponential format (including float and double), and is essentially similar to the relative error. For example, correctly rounded values have an error of no more than 0.5 ULP.

```
_declspec(naked) float _vectorcall cbr(float x)
{
  static const float ct[4] =   // Constants table
  {
    0.333333224f,              // Approximately 1/3
    1.07374182E9f,             // 2^30
    3.0f,                      // 3
    3072.0f                    // 3*2^10
  };
  _asm
  {
    mov ecx,offset ct          // ecx is the address of constants table
    mov ax,0x5555              // ax is approximately coefficient 2^16/3
    vmovss xmm3,[ecx]          // xmm3 = 1/3 approximately
      cbr_sub:                 // Handling of subnormal numbers
    add ecx,4                  // Move the pointer to the next coefficient
    vmovaps xmm1,xmm0          // Duplicate argument x in xmm1
    vmovd edx,xmm0             // edx is a binary representation of x
    vmulss xmm0,xmm0,[ecx]     // xmm0 = x*2^30 - try to normalize x (if needed)
    shr edx,15                 // Get the sign at bit 16 of edx, exponent - at dh
    vucomiss xmm0,xmm1         // Compare x to x*2^30 
    jz cbr_end                 // Do not change the values +-0, +-Inf and NaN
    test dh,dh                 // dh=0 if the number is subnormal
    jz cbr_sub                 // Jump if x is the subnormal number
    mul dx                     // dx is approximately 2/3 of high word |x|
    add dx,0x549B              // Add the "magic" constant
    shl edx,15                 // Form the initial approximation bits
    vmovd xmm0,edx             // xmm0 = y0 - initial approximation for Newton's method
    vmulss xmm2,xmm0,xmm0      // xmm2 = y0^2
    vaddss xmm0,xmm0,xmm0      // xmm0 = 2*y0
    vdivss xmm2,xmm1,xmm2      // xmm2 = x/y0^2
    vaddss xmm0,xmm0,xmm2      // xmm0 = 2*y0+x/y0^2
    vmulss xmm0,xmm0,xmm3      // xmm0 = (2*y0+x/y0^2)/3 = y1
    vmulss xmm2,xmm0,xmm0      // xmm2 = y1^2
    vaddss xmm0,xmm0,xmm0      // xmm0 = 2*y1
    vdivss xmm2,xmm1,xmm2      // xmm2 = x/y1^2
    vaddss xmm0,xmm0,xmm2      // xmm0 = 2*y1+x/y1^2
    vmulss xmm0,xmm0,xmm3      // xmm0 = (2*y1+x/y1^2)/3 = y2
    vmulss xmm2,xmm0,xmm0      // xmm2 = y2^2
    vaddss xmm0,xmm0,xmm0      // xmm0 = 2*y2
    vdivss xmm2,xmm1,xmm2      // xmm2 = x/y2^2
    vaddss xmm0,xmm0,xmm2      // xmm0 = 2*y2+x/y2^2
    vdivss xmm0,xmm0,[ecx+4]   // xmm0 = (2*y2+x/y2^2)/3 = y3 - solution
      cbr_end:                 // Result in xmm0 is done
    ret                        // Return
  }
}
```

Edit Summary*

Cancel

re; "and is almost as accurate — the maximum error is about 1 ULP" please add assume readers know nothing and add a comment what ULP is. Ultimate Lip Pucker is probably wrong :)

Mark Schultheiss
– Mark Schultheiss

2025-08-07 15:01:33 +00:00
Commented Aug 7 at 15:01
ULP — Unit of Last Position. That is, this is an expression of the error in units of the least significant binary digit of the mantissa. It is convenient to use for numbers presented in exponential format (including float and double), and is essentially similar to the relative error. For example, correctly rounded values have an error of no more than 0.5 ULP.

aenigma
– aenigma

2025-08-07 15:46:15 +00:00
Commented Aug 7 at 15:46
1

Thank you! I really love this answer 👍

borealis-c
– borealis-c

2025-08-08 12:14:25 +00:00
Commented Aug 8 at 12:14

Add a comment |

Correct minor typos or mistakes
Clarify meaning without changing it
Add related resources or links
Always respect the author’s intent
Don’t use edits to reply to the author

create code fences with backticks ` or tildes ~
```
like so
```
add language identifier to highlight code
```python
def function(foo):
print(foo)
```
put returns between paragraphs
for linebreak add 2 spaces at end
_italic_ or **bold**
indent code by 4 spaces
backtick escapes `like _so_`
quote by placing > at start of line
to make links (use https whenever possible)

<https://example.com>

[example](https://example.com)

<a href="https://example.com">example</a>

formatting help »
answering help »

Collectives™ on Stack Overflow

How can I obtain the cube root in C++?

Answer*