blob: 34ce2027058a7e0c48e1f3f5a0b85dcb907655f2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
::**************************************************************************************************
::Copyright (C) 2024 The Qt Company Ltd.
::SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
::**************************************************************************************************
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::clean.cmd
:: * Deletes all build-time outputs (removes all 'bin' and 'obj' directories)
:: * Generates version log
:: * Restores NuGet packages
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
IF "%BUILD_PLATFORM%" == "" (
SET BUILD_PLATFORM=%VSCMD_ARG_TGT_ARCH%
)
ECHO.
%##########################%
%##% %BOLD%Deleting output files...%RESET%
%##########################%
RD /S /Q bin > NUL 2>&1
FOR /F %ALL% %%d IN (`DIR /A:D /B /S bin 2^> NUL`) DO (
RD /S /Q %%d > NUL 2>&1
)
RD /S /Q obj > NUL 2>&1
FOR /F %ALL% %%d IN (`DIR /A:D /B /S obj 2^> NUL`) DO (
RD /S /Q %%d > NUL 2>&1
)
CALL %SCRIPTLIB%\log_version.cmd
ECHO.
%##########################%
%##% %BOLD%Restoring packages...%RESET%
IF %VERBOSE% (
%##% msbuild: vstools.sln
%##% msbuild: -t:Restore
%##% msbuild: -p:Configuration=%BUILD_CONFIGURATION%
%##% msbuild: -p:Platform=%BUILD_PLATFORM%
%##% msbuild extras: %MSBUILD_EXTRAS%
)
%##########################%
IF NOT %VERBOSE% ECHO %DARK_GRAY%
msbuild ^
-nologo ^
-verbosity:%MSBUILD_VERBOSITY% ^
-t:Restore ^
-p:Configuration=%BUILD_CONFIGURATION% ^
-p:Platform=%BUILD_PLATFORM% ^
%MSBUILD_EXTRAS% ^
vstools.sln
ECHO %RESET%
IF %ERRORLEVEL% NEQ 0 (
CALL %SCRIPTLIB%\error.cmd %ERRORLEVEL% "ERROR restoring packages!"
EXIT /B %ERRORLEVEL%
)
|
